Inheritance #

Dictionary



Table of contents

Dictionary #

Variant, builtin_classes

A built-in data structure that holds key-value pairs.

Dictionaries are associative containers that contain values referenced by unique keys. Dictionaries will preserve the insertion order when adding new entries. In other programming languages, this data structure is often referred to as a hash map or an associative array.

You can define a dictionary by placing a comma-separated list of key: value pairs inside curly braces {}.

Creating a dictionary:

GDScript

var my_dict = {} # Creates an empty dictionary.

var dict_variable_key = "Another key name"
var dict_variable_value = "value2"
var another_dict = {
    "Some key name": "value1",
    dict_variable_key: dict_variable_value,
}

var points_dict = {"White": 50, "Yellow": 75, "Orange": 100}

# Alternative Lua-style syntax.
# Doesn't require quotes around keys, but only string constants can be used as key names.
# Additionally, key names must start with a letter or an underscore.
# Here, `some_key` is a string literal, not a variable!
another_dict = {
    some_key = 42,
}

C#

var myDict = new Godot.Collections.Dictionary(); // Creates an empty dictionary.
var pointsDict = new Godot.Collections.Dictionary
{
    {"White", 50},
    {"Yellow", 75},
    {"Orange", 100}
};

You can access a dictionary's value by referencing its corresponding key. In the above example, points_dict["White"] will return 50. You can also write points_dict.White, which is equivalent. However, you'll have to use the bracket syntax if the key you're accessing the dictionary with isn't a fixed string (such as a number or variable).

GDScript

@export_enum("White", "Yellow", "Orange") var my_color: String
var points_dict = {"White": 50, "Yellow": 75, "Orange": 100}
func _ready():
    # We can't use dot syntax here as `my_color` is a variable.
    var points = points_dict[my_color]

C#

[Export(PropertyHint.Enum, "White,Yellow,Orange")]
public string MyColor { get; set; }
private Godot.Collections.Dictionary _pointsDict = new Godot.Collections.Dictionary
{
    {"White", 50},
    {"Yellow", 75},
    {"Orange", 100}
};

public override void _Ready()
{
    int points = (int)_pointsDict[MyColor];
}

In the above code, points will be assigned the value that is paired with the appropriate color selected in my_color.

Dictionaries can contain more complex data:

GDScript

var my_dict = {
    "First Array": [1, 2, 3, 4] # Assigns an Array to a String key.
}

C#

var myDict = new Godot.Collections.Dictionary
{
    {"First Array", new Godot.Collections.Array{1, 2, 3, 4}}
};

To add a key to an existing dictionary, access it like an existing key and assign to it:

GDScript

var points_dict = {"White": 50, "Yellow": 75, "Orange": 100}
points_dict["Blue"] = 150 # Add "Blue" as a key and assign 150 as its value.

C#

var pointsDict = new Godot.Collections.Dictionary
{
    {"White", 50},
    {"Yellow", 75},
    {"Orange", 100}
};
pointsDict["Blue"] = 150; // Add "Blue" as a key and assign 150 as its value.

Finally, dictionaries can contain different types of keys and values in the same dictionary:

GDScript

# This is a valid dictionary.
# To access the string "Nested value" below, use `my_dict.sub_dict.sub_key` or `my_dict["sub_dict"]["sub_key"]`.
# Indexing styles can be mixed and matched depending on your needs.
var my_dict = {
    "String Key": 5,
    4: [1, 2, 3],
    7: "Hello",
    "sub_dict": {"sub_key": "Nested value"},
}

C#

// This is a valid dictionary.
// To access the string "Nested value" below, use `((Godot.Collections.Dictionary)myDict["sub_dict"])["sub_key"]`.
var myDict = new Godot.Collections.Dictionary {
    {"String Key", 5},
    {4, new Godot.Collections.Array{1,2,3}},
    {7, "Hello"},
    {"sub_dict", new Godot.Collections.Dictionary{{"sub_key", "Nested value"}}}
};

The keys of a dictionary can be iterated with the for keyword:

GDScript

var groceries = {"Orange": 20, "Apple": 2, "Banana": 4}
for fruit in groceries:
    var amount = groceries[fruit]

C#

var groceries = new Godot.Collections.Dictionary{{"Orange", 20}, {"Apple", 2}, {"Banana", 4}};
foreach (var (fruit, amount) in groceries)
{
    // `fruit` is the key, `amount` is the value.
}

Note: Dictionaries are always passed by reference. To get a copy of a dictionary which can be modified independently of the original dictionary, use duplicate.

Note: Erasing elements while iterating over dictionaries is not supported and will result in unpredictable behavior.

Members #

Methods #

func assign(dictionary: Dictionary) -> void#

Assigns elements of another dictionary into the dictionary. Resizes the dictionary to match dictionary. Performs type conversions if the dictionary is typed.

func clear() -> void#

Clears the dictionary, removing all entries from it.

const func duplicate(deep: bool = false) -> Dictionary#

Creates and returns a new copy of the dictionary. If deep is true, inner Dictionary and Array keys and values are also copied, recursively.

func erase(key: Variant) -> bool#

Removes the dictionary entry by key, if it exists. Returns true if the given key existed in the dictionary, otherwise false.

Note: Do not erase entries while iterating over the dictionary. You can iterate over the keys array instead.

const func find_key(value: Variant) -> Variant#

Finds and returns the first key whose associated value is equal to value, or null if it is not found.

Note: null is also a valid key. If inside the dictionary, find_key may give misleading results.

const func get(default: Variant = null) -> Variant#

Returns the corresponding value for the given key in the dictionary. If the key does not exist, returns default, or null if the parameter is omitted.

func get_or_add(default: Variant = null) -> Variant#

Gets a value and ensures the key is set. If the key exists in the dictionary, this behaves like get. Otherwise, the default value is inserted into the dictionary and returned.

const func get_typed_key_builtin() -> int#

Returns the built-in Variant type of the typed dictionary's keys as a Variant.Type constant. If the keys are not typed, returns TYPE_NIL. See also is_typed_key.

const func get_typed_key_class_name() -> StringName#

Returns the built-in class name of the typed dictionary's keys, if the built-in Variant type is TYPE_OBJECT. Otherwise, returns an empty StringName. See also is_typed_key and Object.get_class.

const func get_typed_key_script() -> Variant#

Returns the Script instance associated with this typed dictionary's keys, or null if it does not exist. See also is_typed_key.

const func get_typed_value_builtin() -> int#

Returns the built-in Variant type of the typed dictionary's values as a Variant.Type constant. If the values are not typed, returns TYPE_NIL. See also is_typed_value.

const func get_typed_value_class_name() -> StringName#

Returns the built-in class name of the typed dictionary's values, if the built-in Variant type is TYPE_OBJECT. Otherwise, returns an empty StringName. See also is_typed_value and Object.get_class.

const func get_typed_value_script() -> Variant#

Returns the Script instance associated with this typed dictionary's values, or null if it does not exist. See also is_typed_value.

const func has(key: Variant) -> bool#

Returns true if the dictionary contains an entry with the given key.

GDScript

var my_dict = {
    "Godot" : 4,
    210 : null,
}

print(my_dict.has("Godot")) # Prints true
print(my_dict.has(210))     # Prints true
print(my_dict.has(4))       # Prints false

C#

var myDict = new Godot.Collections.Dictionary
{
    { "Godot", 4 },
    { 210, default },
};

GD.Print(myDict.ContainsKey("Godot")); // Prints True
GD.Print(myDict.ContainsKey(210));     // Prints True
GD.Print(myDict.ContainsKey(4));       // Prints False

In GDScript, this is equivalent to the in operator:

if "Godot" in {"Godot": 4}:
    print("The key is here!") # Will be printed.

Note: This method returns true as long as the key exists, even if its corresponding value is null.

const func has_all(keys: Array) -> bool#

Returns true if the dictionary contains all keys in the given keys array.

var data = {"width" : 10, "height" : 20}
data.has_all(["height", "width"]) # Returns true

const func hash() -> int#

Returns a hashed 32-bit integer value representing the dictionary contents.

GDScript

var dict1 = {"A": 10, "B": 2}
var dict2 = {"A": 10, "B": 2}

print(dict1.hash() == dict2.hash()) # Prints true

C#

var dict1 = new Godot.Collections.Dictionary{{"A", 10}, {"B", 2}};
var dict2 = new Godot.Collections.Dictionary{{"A", 10}, {"B", 2}};

// Godot.Collections.Dictionary has no Hash() method. Use GD.Hash() instead.
GD.Print(GD.Hash(dict1) == GD.Hash(dict2)); // Prints True

Note: Dictionaries with the same entries but in a different order will not have the same hash.

Note: Dictionaries with equal hash values are not guaranteed to be the same, because of hash collisions. On the contrary, dictionaries with different hash values are guaranteed to be different.

const func is_empty() -> bool#

Returns true if the dictionary is empty (its size is 0). See also size.

const func is_read_only() -> bool#

Returns true if the dictionary is read-only. See make_read_only. Dictionaries are automatically read-only if declared with const keyword.

const func is_same_typed(dictionary: Dictionary) -> bool#

Returns true if the dictionary is typed the same as dictionary.

const func is_same_typed_key(dictionary: Dictionary) -> bool#

Returns true if the dictionary's keys are typed the same as dictionary's keys.

const func is_same_typed_value(dictionary: Dictionary) -> bool#

Returns true if the dictionary's values are typed the same as dictionary's values.

const func is_typed() -> bool#

Returns true if the dictionary is typed. Typed dictionaries can only store keys/values of their associated type and provide type safety for the [] operator. Methods of typed dictionary still return Variant.

const func is_typed_key() -> bool#

Returns true if the dictionary's keys are typed.

const func is_typed_value() -> bool#

Returns true if the dictionary's values are typed.

const func keys() -> Array#

Returns the list of keys in the dictionary.

func make_read_only() -> void#

Makes the dictionary read-only, i.e. disables modification of the dictionary's contents. Does not apply to nested content, e.g. content of nested dictionaries.

func merge(overwrite: bool = false) -> void#

Adds entries from dictionary to this dictionary. By default, duplicate keys are not copied over, unless overwrite is true.

GDScript

var dict = { "item": "sword", "quantity": 2 }
var other_dict = { "quantity": 15, "color": "silver" }

# Overwriting of existing keys is disabled by default.
dict.merge(other_dict)
print(dict)  # { "item": "sword", "quantity": 2, "color": "silver" }

# With overwriting of existing keys enabled.
dict.merge(other_dict, true)
print(dict)  # { "item": "sword", "quantity": 15, "color": "silver" }

C#

var dict = new Godot.Collections.Dictionary
{
    ["item"] = "sword",
    ["quantity"] = 2,
};

var otherDict = new Godot.Collections.Dictionary
{
    ["quantity"] = 15,
    ["color"] = "silver",
};

// Overwriting of existing keys is disabled by default.
dict.Merge(otherDict);
GD.Print(dict); // { "item": "sword", "quantity": 2, "color": "silver" }

// With overwriting of existing keys enabled.
dict.Merge(otherDict, true);
GD.Print(dict); // { "item": "sword", "quantity": 15, "color": "silver" }

Note: merge is not recursive. Nested dictionaries are considered as keys that can be overwritten or not depending on the value of overwrite, but they will never be merged together.

const func merged(overwrite: bool = false) -> Dictionary#

Returns a copy of this dictionary merged with the other dictionary. By default, duplicate keys are not copied over, unless overwrite is true. See also merge.

This method is useful for quickly making dictionaries with default values:

var base = { "fruit": "apple", "vegetable": "potato" }
var extra = { "fruit": "orange", "dressing": "vinegar" }
# Prints { "fruit": "orange", "vegetable": "potato", "dressing": "vinegar" }
print(extra.merged(base))
# Prints { "fruit": "apple", "vegetable": "potato", "dressing": "vinegar" }
print(extra.merged(base, true))

const func recursive_equal(recursion_count: int) -> bool#

Returns true if the two dictionaries contain the same keys and values, inner Dictionary and Array keys and values are compared recursively.

func set(value: Variant) -> bool#

Sets the value of the element at the given key to the given value. This is the same as using the [] operator (arrayindex = value).

const func size() -> int#

Returns the number of entries in the dictionary. Empty dictionaries ({ }) always return 0. See also is_empty.

func sort() -> void#

Sorts the dictionary in-place by key. This can be used to ensure dictionaries with the same contents produce equivalent results when getting the keys, getting the values, and converting to a string. This is also useful when wanting a JSON representation consistent with what is in memory, and useful for storing on a database that requires dictionaries to be sorted.

const func values() -> Array#

Returns the list of values in this dictionary.

Annotations #

Constants #

Constructors #

Dictionary() -> Dictionary #

Constructs an empty Dictionary.

Dictionary(value_script: Variant) -> Dictionary #

Creates a typed dictionary from the base dictionary. A typed dictionary can only contain keys and values of the given types, or that inherit from the given classes, as described by this constructor's parameters.

Dictionary(from: Dictionary) -> Dictionary #

Returns the same dictionary as from. If you need a copy of the dictionary, use duplicate.

Enums #

Operators #

Dictionary != Dictionary -> bool#

Returns true if the two dictionaries do not contain the same keys and values.

Dictionary == Dictionary -> bool#

Returns true if the two dictionaries contain the same keys and values. The order of the entries does not matter.

Note: In C#, by convention, this operator compares by reference. If you need to compare by value, iterate over both dictionaries.

Dictionary[Variant] -> Variant#

Returns the corresponding value for the given key in the dictionary. If the entry does not exist, fails and returns null. For safe access, use get or has.

Signals #

Theme Items #

Tutorials #